FSD - no HDD is guaranteed not to fail - and if it does your data is in trouble whether it is partitioned or not (and all HDDs have at least one primary or extended partition after they're fdisk'ed anyway). And if the MBR goes then you're shafted unless you've copied it onto a stiffy with a restore program (doesn't apply to NTFS, but that's a much more robust system anyway).
Ya, I remember reading in The Register about the Fujitsu debacle, it was one out-of-spec chip from another source as I remember. Expensive for Fujitsu!
"Personally I ghost my disk onto removable disk then hide it away safe." - best idea, so do I. Lives in a safe in a concrete shed at the bottom of the garden.
No need to spend any time on it really. The venerable XCOPY and a batch file will do it (does anyone write batchfiles anymore these days?). Use a customised batch file similar to SAFETY.BAT below and stuff it (or rather a shortcut to the .PIF) in as a daily/weekly task for Task Scheduler. You can play with the PIF to exit automatically or change the window or whatever.
SAFETY BAT
@echo off
cls
goto START
:NOTE1
Batch file to save selected folders to a secondary drive.
Automate daily/weekly with Task Scheduler.
Change or add the XCOPY sections to suit
:NOTE2
If you are using a removable drive or doing anything that might change
driveletters it is a good idea to build in a check that you are writing
to the intended drive. You can do this by creating a zerolength marker
file in the root of the backup drive, thus
echo > E:\marker1.fil <enter>
and set it read-only
attrib +R E:\marker1.fil <enter>
Here is a check to see that the marker file E:\marker1.fil
is in the root of the [removable] E: drive. If it isn't,
either there is no disk pack in the removable drive or the
wrong pack is in the drive.
:START
if not exist E:\marker1.fil goto error
:DOIT
echo.
echo Working - Please wait...
echo.
XCOPY C:"MyDocs\Soundclips\*.*" E:"MyDocs\Soundclips" /D /R /H /C /S /I /Q /Y
rem add /O for XP
if errorlevel 5 if not errorlevel 6 echo Disk write error occurred
if errorlevel 4 if not errorlevel 5 goto initerr
if errorlevel 2 if not errorlevel 3 echo User halted Xcopy process
if errorlevel 1 if not errorlevel 2 echo No files were found to copy!
If errorlevel 0 if not errorlevel 1 echo.
If errorlevel 0 if not errorlevel 1 echo Xcopy successful!
echo.
XCOPY C:"MyDocs\Words\Posts\*.*" E:"MyDocs\Words\Posts" /D /R /H /C /S /I /Q /Y
rem add /O for XP
if errorlevel 5 if not errorlevel 6 echo Disk write error occurred
if errorlevel 4 if not errorlevel 5 goto initerr
if errorlevel 2 if not errorlevel 3 echo User halted Xcopy process
if errorlevel 1 if not errorlevel 2 echo No files were found to copy!
If errorlevel 0 if not errorlevel 1 echo.
If errorlevel 0 if not errorlevel 1 echo Xcopy successful!
echo.
goto END
:initerr
echo
echo Initialization error occurred.
echo There is not enough memory or disk space.
echo.
echo Most probable cause is that there are too many files to fit
echo on the disk. Check yours filesize totals and try again.
echo.
pause
goto end
:ERROR
echo.
echo ERROR! The marker file was NOT found! Make sure that:
echo.
echo 1: You have no changed or added drive letters.
echo If you have you will need to edit this batchfile
echo 2: That there is a drive in the removable bay.
echo 3: The correct drive is in the removable bay.
echo 4: That the marker file has not been accidentally erased.
echo.
pause
goto END
:END
-------------------------------
Error and omissions excepted. Customise to your own requirements.
Now the batchfile mavens can poke holes in my "programming" and logic..